Remote control fan

Upload this first, open the Serial Monitor (9600 baud), and press buttons on the remote. Write down the codes for POWER, VOL+ and VOL−.

// Session 3 - Remote code finder
#include <IRremote.hpp>

int receiverPin = 11;

void setup() {
  Serial.begin(9600);
  IrReceiver.begin(receiverPin, ENABLE_LED_FEEDBACK);  // the L light blinks when a signal arrives
  Serial.println("Point the remote at the receiver and press buttons...");
}

void loop() {
  if (IrReceiver.decode()) {
    // holding a button sends "repeat" signals - skip those
    if (!(IrReceiver.decodedIRData.flags & IRDATA_FLAGS_IS_REPEAT)) {
      Serial.print("Button code: 0x");
      Serial.println(IrReceiver.decodedIRData.command, HEX);
    }
    IrReceiver.resume();   // get ready for the next button
  }
}

If your codes from Step 1 are different from the ones below, change the three #define lines.

// Session 3 - Remote control fan
#include <IRremote.hpp>

int receiverPin = 11;
int enablePin = 5;   // L293D pin 1
int input1 = 3;      // L293D pin 2
int input2 = 4;      // L293D pin 7

// Button codes for the ELEGOO remote (check yours with the code finder)
#define BTN_POWER    0x45
#define BTN_VOL_UP   0x46
#define BTN_VOL_DOWN 0x15

bool fanOn = false;
int fanSpeed = 200;   // 100 (slow) to 255 (full)

void setup() {
  pinMode(enablePin, OUTPUT);
  pinMode(input1, OUTPUT);
  pinMode(input2, OUTPUT);
  digitalWrite(input1, HIGH);   // pick a direction
  digitalWrite(input2, LOW);

  Serial.begin(9600);
  IrReceiver.begin(receiverPin, ENABLE_LED_FEEDBACK);
  Serial.println("Ready. POWER = on/off, VOL+ / VOL- = speed");
}

void updateFan() {
  if (fanOn) {
    analogWrite(enablePin, fanSpeed);
  } else {
    analogWrite(enablePin, 0);
  }
  Serial.print("Fan: ");
  Serial.print(fanOn ? "ON" : "OFF");
  Serial.print("   speed: ");
  Serial.println(fanSpeed);
}

void loop() {
  if (IrReceiver.decode()) {
    bool isRepeat = IrReceiver.decodedIRData.flags & IRDATA_FLAGS_IS_REPEAT;
    int code = IrReceiver.decodedIRData.command;

    if (!isRepeat) {
      if (code == BTN_POWER) {
        fanOn = !fanOn;
      } else if (code == BTN_VOL_UP) {
        fanSpeed = min(fanSpeed + 25, 255);
      } else if (code == BTN_VOL_DOWN) {
        fanSpeed = max(fanSpeed - 25, 100);   // below about 100 the motor just hums
      }
      updateFan();
    }
    IrReceiver.resume();
  }
}